We use cookies to ensure that we give you the best experience on our website.

Windows でコマンドラインを使用して CSV を Excel (XLS または XLSX) に変換する方法

Windows Speedup Tool をダウンロードしてエラーを修正し、PC の動作を高速化します。

ここにチュートリアルがありますコマンドラインを使用してCSVをXLSまたはXLSXに変換します インタフェースWindows 11/10の場合。 CSV ファイルを Excel 形式 (XLS、XLSX) に変換するには、複数の方法があります。 Microsoft Excel、専用のコンバータ フリーウェア、またはオンライン ツールを使用して変換を実行できます。しかし、Windows コマンドライン インターフェイスを使用して CVS を Excel に変換することもできることをご存知ですか?それに、サードパーティのツールも必要ないのですか?そうでない場合は、このチュートリアルは嬉しい驚きとなるでしょう。

この記事では、CSV ファイルを Excel ブックに変換する方法を説明します。そのために、VBScript を使用します。変換に必要なスクリプトと手順を確認してみましょう。

コマンドラインを使用してCSVをExcelに変換する方法

Windows 11 または Windows 10 のコマンド ライン インターフェイスを使用して CSV を Excel に変換する手順は次のとおりです。

  1. メモ帳を開きます。
  2. Visual Basic スクリプト (VBS) を作成します。
  3. VBS ファイルを保存します。
  4. フォルダー内のコマンド プロンプトを開きます。
  5. CSV から Excel への変換コマンドを入力します。

これらの手順について詳しく説明します。

まず、Windows 10 PC でメモ帳アプリケーションを開きます。次に、関連するコマンドを使用して VBScript を作成する必要があります。以下は、メモ帳に入力する必要がある完全なスクリプトです。ここからコピーしてメモ帳に貼り付けるだけです。

'======================================
' Convert CSV to Excel
'
' arg1: source - CSV path\file
' arg2: target - Excel path\file
'======================================

srccsvfile = Wscript.Arguments(0) 
tgtxlsfile = Wscript.Arguments(1)

'Create Spreadsheet
'Look for an existing Excel instance.
On Error Resume Next ' Turn on the error handling flag
Set objExcel = GetObject(,"Excel.Application")
'If not found, create a new instance.
If Err.Number = 429 Then '> 0
Set objExcel = CreateObject("Excel.Application")
End If

objExcel.Visible = false
objExcel.displayalerts=false

'Import CSV into Spreadsheet
Set objWorkbook = objExcel.Workbooks.open(srccsvfile)
Set objWorksheet1 = objWorkbook.Worksheets(1)

'Adjust width of columns
Set objRange = objWorksheet1.UsedRange
objRange.EntireColumn.Autofit()
'This code could be used to AutoFit a select number of columns
'For intColumns = 1 To 17
' objExcel.Columns(intColumns).AutoFit()
'Next

'Make Headings Bold
objExcel.Rows(1).Font.Bold = TRUE

'Freeze header row
With objExcel.ActiveWindow
.SplitColumn = 0
.SplitRow = 1
End With
objExcel.ActiveWindow.FreezePanes = True

'Add Data Filters to Heading Row
objExcel.Rows(1).AutoFilter

'set header row gray
objExcel.Rows(1).Interior.ColorIndex = 15
'-0.249977111117893

'Save Spreadsheet, 51 = Excel 2017-2010 
objWorksheet1.SaveAs tgtxlsfile, 51

'Release Lock on Spreadsheet
objExcel.Quit()
Set objWorksheet1 = Nothing
Set objWorkbook = Nothing
Set ObjExcel = Nothing

上記のスクリプトを入力した後、ファイルを保存する必要があります。.vbsファイル拡張子。そのためには、ファイル > 名前を付けて保存オプション。 [名前を付けて保存]ダイアログ プロンプトで、次のように設定します。ファイルの種類を指定して保存にすべてのファイル次に、ファイル名に続けて .vbs ファイル拡張子を入力します。その後、「保存」ボタンをクリックして VBS ファイルを保存します。

次に、上記の VBS スクリプトを保存したフォルダーに移動し、このフォルダでコマンドプロンプトを開きます。

次に、CMD で以下の構文を使用してコマンドを入力する必要があります。

VBSFilename [Input CSV file with path] [Output Excel file with path]

VBS ファイルに「csv-to-excel」という名前を付けた場合、コマンドは次のようになります。

csv-to-excel C:\Users\KOMAL\Desktop\twc.csv C:\Users\KOMAL\Desktop\twc1.xlsx

古いファイル拡張子、つまり XLS を持つ Excel ファイルを作成したい場合は、次のように置き換えてください。xlsxとxls。以下に例を示します。

csv-to-excel C:\Users\KOMAL\Desktop\twc.csv C:\Users\KOMAL\Desktop\twc1.xls

入力 CSV ファイルと出力 Excel ファイルの両方の絶対パスを指定する必要があることに注意してください。

上記のコマンドを入力すると、出力 Excel ファイルが取得されます。

上記の VBScript には、列幅の調整、ペインの固定、フィルターの適用、ヘッダーの太字化などのオプションがあります。VBScript を簡単に調整してこれらのオプションをカスタマイズし、CMD を通じて CSV を Excel に変換するコマンドを実行できます。プログラマーの場合は、それに応じてスクリプトをさらにカスタマイズできます。

これは、VBScript を使用してコマンドラインを使用して CSV を Excel に変換する方法です。ジェフが作成した。

関連記事:

Also Read